Mtok-blog

E4Xは非常に強力なのでXMLから値を検索したり、特定の値を持つ要素をとり除くたりといった処理が簡単にできます。

package
{
	import flash.display.Sprite;
	/**
	 * ...
	 * @author Motoki Matsumoto
	 */
	public class E4XFiltering extends Sprite
	{
		private var _xml:XML =
		<books xmlns = "http://book/namespace/" xmlns:p = "http://parson/namespace/" >
			<book name="PHPで作る携帯サイトデベロッパーズガイド" price ="3150">
				<author>
					<p:parson p:name="滝下 真玄" uri="http://blog.ecworks.jp/" />
				</author>
			</book>
			<book name="PHP×携帯サイト 実践アプリケーション集" price="2940">
				<author>株式会社マイネット・ジャパン</author>
				<author>
					<p:parson p:name="平島 浩一郎" />
				</author>
				<author>
					<p:parson p:name="伊藤 祐策" />
				</author>
				<author>
					<p:parson p:name="中元 正也" />
				</author>
			</book>
			<book name="PHP×携帯サイト デベロッパーズバイブル" price="2940">
				<author>
					<p:parson p:name="荒木 稔" uri="http://memokami.com/" />
				</author>
			</book>
			<book name="Adobe Flex 3 & AIRではじめるアプリケーション開発" price="4410">
				<author>
					<p:parson p:name="公門 和也" />
				</author>
				<author>
					<p:parson p:name="大谷 晋平" />
				</author>
				<author>
					<p:parson p:name="堀越 悠久史" />
				</author>
			</book>
		</books>
		public function E4XFiltering()
		{
			//
			var book:Namespace = new Namespace('http://book/namespace/');
			var parson:Namespace = new Namespace('http://parson/namespace/');
			trace(_xml.book::book);

			//authorが複数いる本を探す。
			trace(_xml.book::book.(book::author.length() > 1));

			//本のタイトルにFlexを含む本を探す
			trace(_xml.book::book.( /flex/i.test(@name) ));

			//価格が2900円カラ3500円の本を探す
			trace(_xml.book::book.( @price > 2900 && @price < 3500 ));

			//著者の名前をリストアップ
			trace(_xml..parson::parson.@parson::name);

			//uriをもつ著者のみをリストアップ
			trace( _xml..parson::parson.( hasOwnProperty( new QName( parson, '@uri') ) ) );
		}
	}
}